ankafilters/src/kernels/CMakeLists.txt

cmake_minimum_required(VERSION 2.6)

# make burst backprojection kernels
set(COMMON_TEMPLATE templates/common.in)
set(Z_TEMPLATE templates/z_template.in)
set(GENERATOR tools/make_burst_kernels.py)
set(Z_KERNEL z_kernel.cl)

add_custom_command(
    OUTPUT ${Z_KERNEL}
    COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/${GENERATOR} ${GENERATOR}
    COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/${COMMON_TEMPLATE} ${COMMON_TEMPLATE}
    COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/${Z_TEMPLATE} ${Z_TEMPLATE}
    COMMAND python ${GENERATOR} ${Z_TEMPLATE} 1 > ${Z_KERNEL}
    COMMAND python ${GENERATOR} ${Z_TEMPLATE} ${BP_BURST} >> ${Z_KERNEL}
    DEPENDS ${GENERATOR} ${COMMON_TEMPLATE} ${Z_TEMPLATE}
    COMMENT "Generating burst backprojection kernels")

add_custom_target(burst ALL
    DEPENDS ${Z_KERNEL})

install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${Z_KERNEL} DESTINATION ${UFO_ANKAFILTERS_KERNELDIR})

# copy kernels
file(GLOB ufofilter_KERNELS "*.cl")

foreach(_kernel ${ufofilter_KERNELS})
    install(FILES ${_kernel} DESTINATION ${UFO_ANKAFILTERS_KERNELDIR})
endforeach()